*****************************************************************************
* EPC Space GaN Power Device Library
* (C) Copyright EPC Space, LLC. All rights reserved.
* ***************************************************************************
* Version History:
*        Initial:            EPC7020G LTSPICE Model -- 11/20/23
* 2.00: 11/20/2023		Added Source Sense Pin / 4th Pin "sources"
* 3.00: 11/22/2023		Edited Pin Syntax
*****************************************************************************
.subckt EPC7020G drainin gatein sourcein sources
.param aWG      = 1351.0
+A1             = {1.0764e-01*aWg}
+Voff           = 2.0421e+00
+rpara          = 6.0000e-03
+Vdsat          = 5.0000e-01
+ua             = 1.0000e-01
+Vgshape        = 5.4185e+00
+k3             = 9.0000e-02
+rpara_s_factor = 1.0057e-01
+A1_TC          = 2.9190e-03
+Voff_TC        = 6.3105e-04
+Vdsat_TC       = 1.0000e-03
+rpara_TC       = -8.9265e-03
+Vgshape_TC     = 9.6799e-04
+pack_indd      = 1.3000e-09
+pack_inds      = 1.3000e-09
+pack_indg      = 4.000e-09
+pack_rd        = 5.2000e-04
+pack_rs        = 5.2000e-04
+pack_rg        = 0.0000e+00
+cgs0           = {8.7700e-13*aWg}
+cgs_a          = {9.4100e-13*aWg}
+cgs_av         = 1.5586e+00
+cgs_aw         = 1.5068e-01
+cgs_b          = 0.0000e+00
+cgs_bv         = 7.4800e+01
+cgs_bw         = 1.0550e+01
+cgd0           = {2.4300e-15*aWg}
+cgd_a          = {1.3700e-13*aWg}
+cgd_av         = -7.3611e+00
+cgd_aw         = 4.3140e+00
+cgd_b          = {1.1700e-14*aWg}
+cgd_bv         = -2.5890e+01
+cgd_bw         = 2.2935e+01
+cgd_c          = 0.0000e+00
+cgd_cv         = -3.3260e+01
+cgd_cw         = 8.9000e-01
+csd0           = {3.8000e-13*aWg}
+csd_a          = {4.7100e-13*aWg}
+csd_av         = -1.7350e+01
+csd_aw         = 1.4479e+00
+csd_b          = {5.0700e-13*aWg}
+csd_bv         = -3.0140e+01
+csd_bw         = 3.9939e+01
+csd_c          = 0.0000e+00
+csd_cv         = -8.1250e+01
+csd_cw         = 5.6650e+00
+rg_value       = 0.4
+dgs1           = 4.300e-07
+dgs2           = 2.600e-13
+dgs3           = 8.0000e-01
+dgs4           = 2.3000e-01



*Define commonly used functions
.func Voff_T(Temp)={Voff*(1-Voff_TC*(Temp-25))}
.func Vdsat_T(Temp)={smthpos(Vdsat*(1+Vdsat_TC*(Temp-25)),0.1)}
.func f_cust(Vab,loc,wid)={wid*log(1+exp((Vab-loc)/wid))}
.func smthpos(y,d)={0.5*(sqrt(y*y + d*d) + y)}



rd drainin dmid {(pack_rd+((1-rpara_s_factor)*rpara))*(1-rpara_TC*(Temp-25))}
rs sourcein smid {(rpara_s_factor*rpara*(1-rpara_TC*(Temp-25)))}
rss smid sources {pack_rs}
rg gmid gate {pack_rg+rg_value}

Ld drainin dmid {pack_indd} rser = 0
Ls sourcein smid {pack_inds} rser = 0 
Lg gatein gmid {pack_indg} rser = 0

Rcsdconv drain source {100000Meg/aWg}
Rcgsconv gate source {100000Meg/aWg}
Rcgdconv gate drain {100000Meg/aWg}


bswitch drain source I=if(v(drain,source)>0,
+   (A1*(1-A1_TC*(Temp-25))*
+   f_cust(v(gate,source),Voff_T(Temp),k3)* 
+   v(drain,source)/
+   (v(drain,source)+
+   Vdsat_T(Temp)*
+   smthpos((1 - (v(gate,source)-Voff_T(Temp))/
+   (Vgshape*(1+Vgshape_TC*(Temp-25)))),0.1))*
+   1.0/(1.0 + ua*smthpos((v(gate,source)-Voff_T(Temp)),0.1))),
+   (-A1*(1-A1_TC*(Temp-25))*
+   f_cust(v(gate,drain),Voff_T(Temp),k3)* 
+   v(source,drain)/
+   (v(source,drain)+
+   Vdsat_T(Temp)*
+   smthpos((1 - (v(gate,drain)-Voff_T(Temp))/
+   (Vgshape*(1+Vgshape_TC*(Temp-25)))),0.1))*
+   1.0/(1.0 + ua*smthpos((v(gate,drain)-Voff_T(Temp)),0.1)))
+   )

bgsdiode gate source I=if( v(gate,source)>10,
+   (0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))),
+   (0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1))))

bgddiode gate drain I=if( v(gate,drain)>10,
+   (0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))),
+   (0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1))) )

C_GS       	gate source {cgs0}
C_CGS1    	gate source Q=(0.5*cgs_a*cgs_aw*log(1+exp((v(gate,source)-cgs_av)/cgs_aw))+
+           cgs_b*cgs_bw*log(1+exp((v(source,drain)-cgs_bv)/cgs_bw)) )

C_GD      	gate drain {cgd0}
C_CGD1    	gate drain Q=(0.5*cgs_a*cgs_aw*log(1+exp((v(gate,drain)-cgs_av)/cgs_aw))+
+           cgd_a*cgd_aw*log(1+exp((v(gate,drain)-cgd_av)/cgd_aw))+
+           cgd_b*cgd_bw*log(1+exp((v(gate,drain)-cgd_bv)/cgd_bw))+ 
+           cgd_c*cgd_cw*log(1+exp((v(gate,drain)-cgd_cv)/cgd_cw)))

C_SD       	source drain {csd0}
C_CSD1	    source drain Q=(csd_a*csd_aw*log(1+exp((v(source,drain)-csd_av)/csd_aw))+
+           csd_b*csd_bw*log(1+exp((v(source,drain)-csd_bv)/csd_bw))+
+           csd_c*csd_cw*log(1+exp((v(source,drain)-csd_cv)/csd_cw)))

.ends

*****************************************************************************